Exploring Where & Why/Exploring Where & Why.iso/pc/Lib.cst/00121_sound handling.ls

Text File | 2004-07-11 | 5.0 KB | 164 lines

-- SOUND handlers
-- all effect sounds are played in channel 1

-- this global is available to all the handlers below it
global gSoundList

------------------------------------------------------------------------------------
-- this intializes the global response sound list
-- pass it 2 lists of sounds, good and bad, and it arranges them into a
-- property list
--
-- the call should look something like this:
-- initSoundList(["good1.aiff", "good2.aiff", "good3.aiff"], ["bad.aiff", "verybad.aiff"])
--
-- since the sounds are stored internally in a director shared cast, the names have to be
-- the full names of the sound cast members.
on initSoundList

  set goodSoundNames = ["good,1","good,2","good,3","good,4","good,5","good,6","good,7","good,8","good,9","good,10","good,11","good,12","good,13","good,14","good,15","good,16","good,17","good,18","good,19","good,20"]

  set badSoundNames = ["try again,boy", "try again,girl"]

  set goodNoiseNames = ["goodNoise,1", "goodNoise,3", "goodNoise,4", "goodNoise,5", "goodNoise,6", "goodNoise,7"]

  set badNoiseNames = ["badNoise,1", "badNoise,2", "badNoise,3", "badNoise,4", "badNoise,5", "badNoise,6", "badNoise,7", "badNoise,8"]


  set gSoundList = [:]

  -- add the good sound cast numbers
  set tempList = []
  repeat with x in goodSoundNames
    add(tempList, the memberNum of member x)
  end repeat

  -- now add the good tag and the list
  addProp(gSoundList, #goodSounds, tempList)


  -- now do the same for the bad sounds
  set tempList = []
  repeat with x in badSoundNames
    add(tempList, the memberNum of member x)
  end repeat

  -- now add the good tag and the list
  addProp(gSoundList, #badSounds, tempList)


  -- now do the same for the bad sounds
  set tempList = []
  repeat with x in goodNoiseNames
    add(tempList, the memberNum of member x)
  end repeat

  -- now add the good tag and the list
  addProp(gSoundList, #goodNoises, tempList)

  -- now do the same for the bad sounds
  set tempList = []
  repeat with x in badNoiseNames
    add(tempList, the memberNum of member x)
  end repeat

  -- now add the good tag and the list
  addProp(gSoundList, #badNoises, tempList)

end

------------------------------------------------------------------------------------
-- this will play a good or bad sound from the global list
--
-- It takes several params:
-- sndType = good or bad, pass a 1 for good, and a 0 for bad
-- loopTillDone = shuld we immediately go on, or should we sit in this handler until
--                the sound in channel 1 is finished? pass a 1 for wait for it, and a 0 for go on
-- directRef = if you want to refer to one of the sounds in particular, for instance, if I
--             always wanted to play "good3.aiff", I would call the function like this:
--             playResponseSound(1, 1, 3) and this would play the 3rd "good" sound in
--             the global list.

on playResponseSound sndType, loopTillDone, directRef
  global gUI

  -- first get the correct list from the global list holder
  set thisList = []

  -- if we are looking for a positive sound
  if sndType then
    set thisList = value(the goodSounds of gSoundList)
    set noiseList = value (the goodNoises of gSoundList)
  else
    set thisList = value(the badSounds of gSoundList)
    set noiseList = value (the badNoises of gSoundList)
  end if

  -- now we need to pick a sound

  -- get a random noise:
  set thisNoise = getAt (noiseList, random (count (noiseList)))


  -- we are not asking for a specific sound
  if voidP(directRef) then

    -- we should get a random sound
    set thisSound = getAt(thisList, random(count(thisList)))

  else
    -- if the directRef sound is not there, then do the random thing
    if directRef > count(thisList) or directRef < 1 then
      put "doing random soundage because that sound is unavailable..!"
      set thisSound = getAt(thisList, random(count(thisList)))
    else
      set thisSound = getAt(thisList, directRef)
    end if

  end if

  -- now we should check to make sure we have a valid sound cast number in thisSound
  if thisSound > 0 then
    -- we should play the sound
    puppetSound 1, member thisNoise of castLib "UI.cst"
    updateStage

    -- wait while it plays
    waitFXSound(#lock)

    -- should it wait?
    if loopTillDone then
      puppetSound 1, member thisSound of castLib "UI.cst"
      updateStage

      -- wait while it plays
      waitFXSound()
    else
      -- just fire it off
      puppetSound 1, member thisSound of castLib "UI.cst"
      updateStage
    end if

    -- eat the mouse clicks
    clearEvents(gUI)

    -- we successfully played the sound
    return 1

  else

    -- we bailed out for some reason
    return 0
  end if

end

------------------------------------------------------------------------------------
-- wait for the sound in the FX channel to stop
on waitFXSound cmd
  repeat while soundBusy(1)
    updateStage
    if the mouseDown and not cmd = #lock then exit repeat
  end repeat
end